# Maintainer: FWS
# Dépendance de l'installateur Anaconda (rhinstaller) — framework TUI texte.
# Pur Python (setuptools find_packages, aucune extension C) : on installe
# l'arborescence à la main pour éviter d'exiger python-build/python-installer.
pkgname=python-simpleline
pkgver=1.8
pkgrel=1
pkgdesc="Python3 text UI framework (dépendance Anaconda)"
arch=('any')
url="https://github.com/rhinstaller/python-simpleline"
license=('LGPL-3.0-or-later')
depends=('python' 'python-gobject')
_tag="simpleline-$pkgver"
source=("$pkgname-$pkgver.tar.gz::https://github.com/rhinstaller/python-simpleline/archive/refs/tags/$_tag.tar.gz")
sha256sums=('b58cfb3ac4166b8bbbd1d3789713dc364c50509a513ead7be66a237a5b3affa3')
_srcdir="python-simpleline-$_tag"

package() {
  cd "$srcdir/$_srcdir"
  local sitedir
  sitedir=$(python -c 'import site; print(site.getsitepackages()[0])')
  install -d "$pkgdir$sitedir"
  cp -a simpleline "$pkgdir$sitedir/simpleline"
  # -d : grave le chemin d'exécution réel dans les .pyc (pas le $pkgdir de build).
  python -m compileall -q -d "$sitedir/simpleline" "$pkgdir$sitedir/simpleline" || true
  install -Dm644 LICENSE.md "$pkgdir/usr/share/licenses/$pkgname/LICENSE.md"
}
